#
# Chakra Apps for Chakra, part of chakra-project.org
#
# contributor (x86_64): Giuseppe Calà <jiveaxe@gmail.com>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgbase=cherrypy
pkgname=('python2-cherrypy' 'python3-cherrypy')
pkgver=3.2.4
pkgrel=1
pkgdesc="A pythonic, object-oriented web development framework"
arch=('x86_64')
makedepends=('python2' 'python3')
url="http://www.cherrypy.org"
license=('BSD')
categories=('programming')
source=("https://pypi.python.org/packages/source/C/CherryPy/CherryPy-${pkgver}.tar.gz")
md5sums=('e2c8455e15c39c9d60e0393c264a4d16')

build() {
    cd $srcdir/CherryPy-$pkgver
    install -dm 755 $srcdir/build2
    install -dm 755 $srcdir/build3
    cp -R * ../build2
    cp -R * ../build3
}
package_python2-cherrypy() {
depends=('python2')
provides=('cherrypy')
conflicts=('cherrypy')
replaces=('cherrypy')
    cd $srcdir/build2
    python2 ./setup.py install --root=$pkgdir
    # install the lincence file
    install -dm 755 $pkgdir/usr/share/licenses/$pkgname/
    install -D -m644 ${srcdir}/CherryPy-${pkgver}/cherrypy/LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/
    rm $pkgdir/usr/lib/python2.7/site-packages/cherrypy/LICENSE.txt
}

package_python3-cherrypy() {
depends=('python3')
    cd $srcdir/build3
    python3 ./setup.py install --root=$pkgdir
    # rename the binary
    install -Dm 755 $pkgdir/usr/bin/cherryd $pkgdir/usr/bin/cherryd-python3
    rm $pkgdir/usr/bin/cherryd
    # install the lincence file
    install -dm 755 $pkgdir/usr/share/licenses/$pkgname/
    install -D -m644 ${srcdir}/CherryPy-${pkgver}/cherrypy/LICENSE.txt $pkgdir/usr/share/licenses/${pkgname}/
    rm $pkgdir/usr/lib/python3.3/site-packages/cherrypy/LICENSE.txt
}