#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (abveritas[at]chakra-project[dot]org>

pkgbase=avidemux
pkgname=('avidemux-cli' 'avidemux')
pkgver=2.6.4
pkgrel=1
pkgdesc='Simple video editor for cutting, filtering and encoding tasks.'
arch=('x86_64')
license=('GPL')
url="http://fixounet.free.fr/avidemux/"
screenshot="http://upload.wikimedia.org/wikipedia/commons/7/77/Avidemux_Screenshot_Qt.png"
makedepends=('cmake' 'libxslt' 'qt' 'jack' 'libvorbis' 'sdl' 'libxv' 'alsa-lib' 'lame' 'xvidcore'
             'faad2' 'faac' 'x264' 'libsamplerate' 'opencore-amr' 'yasm' 'mesa' 'libvpx'
             'pulseaudio' 'libva' 'desktop-file-utils')
categories=('multimedia')
options=("!makeflags")
source=("http://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz")
sha256sums=('2937c6c09248445942ac7e71b100ff8f7e272c4ad9c38e7d8c519ce4a11cec44')
         
build() {
  cd "${srcdir}/${pkgbase}_${pkgver}"
 # build
  bash ./bootStrap.bash --with-core \
                        --with-cli \
                        --with-qt4 \
                        --without-gtk \
                        --with-plugins

  # Create qm files
  cd po
  lrelease *.po
}

package_avidemux-cli() {
  pkgdesc="A graphical tool to edit video (filter/re-encode/split)"
  depends=('libxv' 'libxml2' 'sdl' 'fontconfig' 'libvpx')
  optdepends=('lame: for the corresponding audio encoder plugin'
              'faac: for the corresponding audio encoder plugin'
              'faad2: for the corresponding audio decoder plugin'
              'opencore-amr: for the corresponding audio decoder plugin'
              'jack: for the corresponding audio device plugin'
              'pulseaudio: for the corresponding audio device plugin'
              'sdl: for the corresponding audio device plugin'
              'x264: for the corresponding video encoder plugin'
              'xvidcore: for the corresponding video encoder plugin')

  cd "${srcdir}/${pkgbase}_${pkgver}"
  (cd buildCli; make DESTDIR="${pkgdir}" install)
  (cd buildCore; make DESTDIR="${pkgdir}" install)
  (cd buildPluginsCLI; make DESTDIR="${pkgdir}" install)
  (cd buildPluginsCommon; make DESTDIR="${pkgdir}" install)
  
  install -D -m644 "${srcdir}/${pkgbase}_${pkgver}/avidemux_icon.png" "${pkgdir}/usr/share/pixmaps/avidemux.png" 
  install -D -m644 "${srcdir}/${pkgbase}_${pkgver}/man/avidemux.1" "${pkgdir}/usr/share/man/man1/avidemux.1" 
}

package_avidemux() {
  pkgdesc="A graphical tool to edit video (filter/re-encode/split)"
  depends=('avidemux-cli' 'qt' 'mesa')

  cd "${srcdir}/${pkgbase}_${pkgver}"
  
  (cd buildQt4; make DESTDIR="${pkgdir}" install)
  (cd buildPluginsQt4; make DESTDIR="${pkgdir}" install)

  install -D -m644 avidemux2.desktop "${pkgdir}/usr/share/applications/avidemux-qt.desktop"
  sed -i 's|2_gtk|3_qt4|' "${pkgdir}/usr/share/applications/avidemux-qt.desktop"

}