#
# Games Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio) <adriyetichaves gmail.com>

pkgname=speed-dreams-data
_pkgname=speed-dreams
pkgver=1.4.0
_pkgver=1.4.0-r2307 # For managing files and directories
pkgrel=2
pkgdesc="A racing simulator with rich graphics and physics (data files)."
arch=('any')
url="http://speed-dreams.sourceforge.net/"
license=('GPL2')
depends=()
makedepends=('enet' 'freealut' 'freeglut' 'libpng' 'libxmu' 'libxrandr' 'libxrender' 'plib>=1.8.3' 'libjpeg' 'zlib')
source=("http://sourceforge.net/projects/${_pkgname}/files/${pkgver}/${_pkgname}-${_pkgver}-src.tar.bz2/download")
md5sums=('92c324c2c47a598dea9278d9a66c5b78')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}-src"
  
  unset LDFLAGS MAKEFLAGS

  ./configure \
    --prefix="/usr/share/${_pkgname}" \
    --x-includes=/usr/include \
    --x-libraries=/usr/lib 
  
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}-src"
  
  make DESTDIR="${pkgdir}" install datainstall

  rm -r "${pkgdir}/usr/share/${_pkgname}/bin"
  rm -r "${pkgdir}/usr/share/${_pkgname}/lib"
  find "${pkgdir}" -type d -exec chmod 755 {} \;
}

# vim:set ts=2 sw=2 et: