# Maintainer: Daniele Cocca <jmc@chakra-project.org>
# Original CCR maintainer: Inkane <neoinkaneglade@aol.com>
# Contributor: Alfonso Fernando Àlvarez < ponchoalv at gmail >
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: James Campos <james.r.campos@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
# Contributor: TIanyi Cui <tianyicui@gmail.com>

pkgname=nodejs
pkgver=0.8.17
pkgrel=1
pkgdesc="Node.js is a platform built on Chrome's JavaScript runtime for easily building fast, scalable network applications."
arch=('i686' 'x86_64')
url='http://nodejs.org/'
license=('MIT')
depends=('python2' 'openssl')
checkdepends=('curl') # curl used for check()
options=('!emptydirs')
source=("http://nodejs.org/dist/v${pkgver}/node-v${pkgver}.tar.gz")
md5sums=('a5e0bce25d3e72dfa507d824e954edea')

build() {
  cd "node-v${pkgver}"

  export PYTHON=python2
  ./configure --prefix=/usr

  make
}

check() {
  cd "node-v${pkgver}"
  make test || true
}

package() {
  cd "node-v${pkgver}"

  make install DESTDIR="${pkgdir}"

  # install docs as per user request
  install -d "${pkgdir}/usr/share/doc/nodejs"
  cp -r doc/api/* \
        "${pkgdir}/usr/share/doc/nodejs"

  install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/nodejs/LICENSE"
}

# vim:set ts=2 sw=2 et: