pkgname=octave
pkgver=4.4.0
pkgrel=1
pkgdesc="A high-level language, primarily intended for numerical computations."
arch=('x86_64')
url="http://www.octave.org"
license=('GPL')
depends=('readline' 'glu' 'fftw' 'curl' 'graphicsmagick' 'glpk' 'hdf5' 'qhull'
         'suitesparse' 'arpack' 'pcre' 'qt5-base' 'fontconfig' 'zlib' 'portaudio' 'qrupdate' 'freetype2' 'gl2ps'
         'qscintilla-qt5' 'libsndfile')
makedepends=('texlive-core' 'gcc-fortran' 'texinfo' 'gnuplot' 'openjdk' 'fltk')
optdepends=('texinfo: for help-support in octave'
	    'gnuplot: alternative plotting'
	    'openjdk: to call Java functions'
            'fltk: FLTK GUI')
source=(ftp://ftp.gnu.org/gnu/octave/octave-$pkgver.tar.gz)
options=('!emptydirs')
sha1sums=('cfdba69b9d44a1d1d5703df967a35ac8142748a3')

build() {
  cd $pkgname-$pkgver
    
  ./configure --prefix=/usr \
              --libexecdir=/usr/lib \
              --enable-shared \
              --disable-static \
              --with-quantum-depth=16 \
              --with-umfpack="-lumfpack -lsuitesparseconfig" 
  MOC=moc UIC=uic
  
  LANG=C make
}

package(){
  cd $pkgname-$pkgver

  make DESTDIR=$pkgdir install

  # add path to ld.so.conf.d
  install -d $pkgdir/etc/ld.so.conf.d
  echo "/usr/lib/$pkgname/$pkgver" > "$pkgdir/etc/ld.so.conf.d/$pkgname.conf"
}