#
# Games Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>

pkgbase=shiboken
_pkgbase=Shiboken
pkgname=("${pkgbase}" "${pkgbase}-generator")
pkgver=1.1.1
_pyver=2.7
pkgrel=2
pkgdesc="Support library for Python bindings."
arch=('i686' 'x86_64')
license=('LGPL')
url="http://www.pyside.org"
depends=("python2" 'qt>=4.7' 'openssl')
makedepends=('cmake' 'automoc4' 'generatorrunner')
source=("http://www.pyside.org/files/${pkgbase}-${pkgver}.tar.bz2")
md5sums=('fa451b6c4f3e06cce283a84550a96fd2')

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"
  mkdir -p build && cd build
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    ..
  make shiboken
  make generator
}

package_shiboken(){
  cd "${srcdir}/${pkgbase}-${pkgver}/build/libshiboken"
  make DESTDIR="${pkgdir}" install
}

package_shiboken-generator() {
  depends=("${depends[@]}" "generatorrunner")
  pkgdesc="Support library for Python bindings (generator)."
  
  cd "${srcdir}/${pkgbase}-${pkgver}/build/generator"
  make DESTDIR="${pkgdir}" install

  mkdir -m 755 -p "${pkgdir}/usr/lib/cmake/${_pkgbase}-${pkgver}"
  install -m 755 ../data/ShibokenConfig.cmake "${pkgdir}/usr/lib/cmake/${_pkgbase}-${pkgver}"
  install -m 755 ../data/ShibokenConfigVersion.cmake "${pkgdir}/usr/lib/cmake/${_pkgbase}-${pkgver}"
  install -m 755 "../data/ShibokenConfig-python${_pyver}.cmake" "${pkgdir}/usr/lib/cmake/${_pkgbase}-${pkgver}"

  mkdir -m 755 -p "${pkgdir}/usr/lib/pkgconfig"
  install -m 755 "../data/${pkgbase}.pc" "${pkgdir}/usr/lib/pkgconfig"
}