# Maintainer: UtG  <utg[dot]chakra.linux[at]gmail[dot]com>

pkgbase=python-cssselect
pkgname=('python2-cssselect' 'python3-cssselect')
pkgver=0.9.1
pkgrel=3
license=('BSD')
arch=('x86_64')
url="http://pypi.python.org/pypi/cssselect"
makedepends=('python2' 'python3')
source=("http://pypi.python.org/packages/source/c/cssselect/cssselect-${pkgver}.tar.gz")
md5sums=('c74f45966277dc7a0f768b9b0f3522ac')

prepare() {
  cp -r cssselect-${pkgver} python2-cssselect-${pkgver}
}

package_python3-cssselect() {
  pkgdesc="A Python3 library that parses CSS3 Selectors and translates them to XPath 1.0"
  depends=('python3')

  cd cssselect-${pkgver}
  python3 setup.py install --root="${pkgdir}/" --optimize=1

  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

package_python2-cssselect() {
  pkgdesc="A Python2 library that parses CSS3 Selectors and translates them to XPath 1.0"
  depends=('python2')

  cd python2-cssselect-${pkgver}

  # Fix python2 shebang
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' cssselect/tests.py

  python2 setup.py install --root="${pkgdir}/" --optimize=1
  
  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}