# Maintainer: UtG <utg[dot]chakra.linux[at]gmail[dot]com>
# Contributors: H W Tovetjärn (totte) <totte@tott.es>
# 		Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

## NOTE: when you update Haskell packages you'll have to update the entire stack to not break it ##

_hkgname=stm
pkgname=haskell-stm
pkgver=2.4.4.1
pkgrel=1
pkgdesc="A modular composable concurrency abstraction"
url="http://hackage.haskell.org/package/stm"
license=('custom:BSD3')
arch=('x86_64')
depends=('ghc')
source=(http://hackage.haskell.org/packages/archive/${_hkgname}/$pkgver/${_hkgname}-$pkgver.tar.gz)
install=${pkgname}.install
options=('strip' 'staticlibs')
md5sums=('480b37cce3d35c11fd67bf9df957ae19')

build() {
    cd "${srcdir}/${_hkgname}-${pkgver}"
    runhaskell Setup configure \
	-O -p \
	--enable-split-objs \
	--enable-shared \
	--prefix=/usr \
	--docdir="/usr/share/doc/${pkgname}" \
	--libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/${_hkgname}-$pkgver"
    install -D -m744 register.sh \
	  "${pkgdir}/usr/share/haskell/${pkgname}/register.sh"
    install -m744 unregister.sh \
	  "${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/${pkgname}/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/stm"

    # License
    install -D -m644 LICENSE \
	  ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
    
    runhaskell Setup copy --destdir="${pkgdir}"
}