# Include global configuration

pkgname=spectacle
pkgver=18.12.2
pkgrel=1
pkgdesc="KDE screenshot capture utility"
arch=(x86_64)
url='https://projects.kde.org/spectacle'
license=(GPL)
depends=(xcb-util-cursor libkipi purpose knewstuff)
makedepends=(extra-cmake-modules kdoctools python3)
conflicts=(kdegraphics-ksnapshot kscreengenie)
replaces=(kdegraphics-ksnapshot kscreengenie)
groups=(kde-applications kdegraphics)
options=('docs' 'debug')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('e85e31de49866b0abc67604668e770fad84921ca2899375cbaab3cfc8434823c'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
  cd ${srcdir}/${pkgname}-${pkgver}
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
   -DCMAKE_INSTALL_PREFIX=/usr \
   -DCMAKE_BUILD_TYPE=Release \
   -DCMAKE_INSTALL_LIBDIR=lib \
   -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}