pkgname=warzone2100
pkgver=3.2.2
pkgrel=1
pkgdesc="3D real-time strategy game where you fight to rebuilt the world destroyed by nuclear war."
arch=('x86_64')
url="https://wz2100.net/"
license=('GPL')
categories=('games')
depends=('libgl' 'openal' 'libjpeg' 'libpng' 'libvorbis' 'libtheora' 'libmad'
	 'physfs' 'mesa' 'quesoglc' 'popt' 'ttf-dejavu' 'qt5-base' 'qt5-script'
	 'qt5-x11extras' 'glew' 'sdl2')
makedepends=('gawk' 'bison' 'flex' 'zip' 'unzip' 'libxrandr' 'asciidoc')
conflicts=('warzone2100-dev')
source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.xz"
	warzone2100.appdata.xml)
sha256sums=('af5a8dfe9e9df3505ef2543e4e62afb1f61a4ee4cc903f8ff7785f3c79779d18'
            'd6fd6bf40bd72d57a2872b3e439bed04f4cd78e0a7b2993de580ed765b80cfc4')

build() {
  cd ${pkgname}-${pkgver}

  # Add missing file from the tarball
  cp ${srcdir}/warzone2100.appdata.xml icons/

  ./configure \
    --prefix=/usr \
    --with-backend=qt \
    --with-distributor="Chakra GNU/Linux"
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
}