# maintainer abveritas@chakra-project.org
# contributor Giuseppe Calà <jiveaxe@gmail.com>

pkgname=lilypond
pkgver=2.18.2
_pkgver=2.18
pkgrel=1
pkgdesc="A music engraving program, devoted to producing the highest-quality sheet music possible."
arch=('x86_64')
url="http://lilypond.org/"
license=('GPL')
depends=('fontconfig' 'freetype2' 'ghostscript'
         'guile' 'pango' 'python')
makedepends=('bison' 'flex' 'fontforge' 'gettext' 'gsfonts'
             'perl' 'texinfo' 't1utils' 'texlive-core' 'texlive-langcyrillic' 'netpbm' 'texi2html' 'dblatex' 'zip' 'imagemagick')
optdepends=('netpbm: building HTML documentation'
            'ttf-kochi-substitute: building HTML documentation'
            'texi2html>=1.82: building HTML documentation'
            'rsync: installing HTML documentation')
categories=('multimedia')
screenshot=('http://createdigitalmusic.com/files/2010/05/frescobaldi.png')
install=$pkgname.install
source=("http://download.linuxaudio.org/${pkgname}/sources/v${_pkgver}/${pkgname}-${pkgver}.tar.gz")
md5sums=('3c4bcbb708d12644668b32bfe82ebf25')

build() {
  cd "$srcdir/lilypond-$pkgver"

  # python2 fix
  for file in $(find . -name '*.py' -print); do
    sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' $file
    sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
  done

  ./configure --prefix=/usr
  make all
}

package() {
  cd "$srcdir/lilypond-$pkgver"
  make DESTDIR="$pkgdir/" install
}