# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=parsec
pkgname=haskell-parsec
pkgver=3.1.3
pkgrel=4
pkgdesc="Monadic parser combinators"
url="http://hackage.haskell.org/package/parsec"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=()
depends=('ghc=7.6.3-1' 'haskell-base>=4.0' 'haskell-bytestring' 'haskell-mtl' 'haskell-text>=0.2' 'haskell-text<0.12')
options=('strip')
source=("http://hackage.haskell.org/packages/archive/parsec/3.1.3/parsec-3.1.3.tar.gz")
install="haskell-parsec.install"
sha512sums=('44eb718b4f76501353c6fb8df30d27d563dbf9e5b7d11bff43ec5e4d2b5325d14e8ca99eaa75fcee2a6944562596b13ba0ee46bc7c7a9658f41ffe13c8aeabf8')

build() {
    cd "${srcdir}/parsec-3.1.3"
    runhaskell Setup configure \
        -O \
        ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } \
        --enable-split-objs \
        --enable-shared \
        --prefix="/usr" \
        --docdir="/usr/share/doc/haskell-parsec" \
        --libsubdir='$compiler/site-local/$pkgid'
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/parsec-3.1.3"
    install -D -m744 register.sh \
        "${pkgdir}/usr/share/haskell/haskell-parsec/register.sh"
    install -m744 unregister.sh \
        "${pkgdir}/usr/share/haskell/haskell-parsec/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/haskell-parsec/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/parsec"

    # License
    install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/haskell-parsec/LICENSE"
    rm -f "${pkgdir}/usr/share/doc/haskell-parsec/LICENSE"

    runhaskell Setup copy --destdir="${pkgdir}"
}