pkgname=dolphin-emu
pkgver=5.0.r7309.10d230a512
pkgrel=1
pkgdesc='A GameCube / Wii / Triforce emulator'
arch=('x86_64')
url='http://www.dolphin-emu.org/'
license=('GPL')
depends=('bluez-libs' 'qt5-base' 'enet' 'ffmpeg' 'libao' 'libevdev' 'mbedtls' 'miniupnpc' 'openal' 'portaudio' 'soundtouch' 'xdg-utils')
makedepends=('cmake' 'qt5-tools' 'git')
optdepends=('pulseaudio: PulseAudio backend')
options=('!emptydirs')
_commit='10d230a512b99aee66f7343481ed13d83557de22'
source=("dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=${_commit}")
sha256sums=('SKIP')

pkgver() {
  cd dolphin-emu

  git describe | sed 's/-/.r/; s/-g/./'
}

prepare() {
  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build
}

build() {
  cd build

  cmake ../dolphin-emu \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DENABLE_QT2='ON' \
    -DENABLE_WX='OFF' \
    -DUSE_SHARED_ENET='ON' \
    -DDISTRIBUTOR='chakralinux.org'
  make
}

package() {
  cd build

  make DESTDIR="${pkgdir}" install
  install -Dm 644 ../dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
}