# Maintainer: Adrián Chaves Fernández (Gallaecio)

# This package requires the rake-contrib gem. Run:
# $ gem install rake-contrib

pkgname=ruby-builder
_pkgname=builder
pkgver=3.2.0
pkgrel=2
pkgdesc="A simple Ruby library to create XML markup and data structures."
arch=('x86_64')
url="http://builder.rubyforge.org"
license=('MIT')
depends=('ruby')
source=("https://github.com/jimweirich/builder/archive/$_pkgname-$pkgver.tar.gz"
        "rake.patch")
md5sums=('41b41666df9cb92529fd58ac250b0524'
         '1a82128b5602f76d9f41d5d313ddf17d')

prepare() {
  cd $srcdir/$_pkgname-$_pkgname-$pkgver
  patch -p1 -i ${srcdir}/rake.patch
}

build() {
  cd $srcdir/$_pkgname-$_pkgname-$pkgver
  rake builder:gem
}

package() {
  cd $srcdir/$_pkgname-$_pkgname-$pkgver/pkg

  local _gemdir=$(ruby -rubygems -e 'puts Gem.default_dir')
  gem install \
    --ignore-dependencies --no-user-install --install-dir $pkgdir$_gemdir \
    $_pkgname-$pkgver.gem

  install -Dm644 $srcdir/$_pkgname-$_pkgname-$pkgver/MIT-LICENSE \
                 $pkgdir/usr/share/licenses/$pkgname/LICENSE
}