# Apps Packages for Chakra, part of chakra-project.org
#
# maintainer abveritas@chakra-project.org

pkgname=tellico
pkgver=2.3.7
pkgrel=2
pkgdesc="A collection manager for KDE"
arch=('x86_64')
url="http://tellico-project.org/"
license=('GPL')
depends=('kde-workspace' 'yaz' 'exempi' 'libksane' 'taglib'
         'libkcddb' 'poppler-qt' 'qjson' 'kdemultimedia-audiocd-kio')
makedepends=('automoc4' 'cmake' 'docbook-xsl')
categories=('office')
screenshot=('http://tellico-project.org/img/main_screen-2.0.jpg')
install=$pkgname.install
source=("http://tellico-project.org/files/${pkgname}-${pkgver}.tar.bz2"
        
"tellico-2.3.7-search.patch::https://projects.kde.org/projects/extragear/office/tellico/repository/revisions/60cdaf66d839f497a6c3f4c951256720f3689b72/diff.diff")
md5sums=('ac4728948c6c603dceeb6e6fe0d04c55'
         '0aa8469cd4243f3c0a18d272de08932e')

build() {
  cd "${srcdir}"

  # Patch for 2.3.7
  # See: http://www.chakra-project.org/bbs/viewtopic.php?id=10270
  pushd ${pkgname}-${pkgver}
  sed -e "13,24d" -i $srcdir/tellico-2.3.7-search.patch
  patch -uNp1 -i $srcdir/tellico-2.3.7-search.patch
  popd

  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr

  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install

  # fix python 2.7 path
  find "$pkgdir" -iname "*.py" | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
}