# Include global configuration

pkgname=keditbookmarks
pkgver=18.04.2
pkgrel=1
pkgdesc="Bookmark Organizer and Editor"
arch=(x86_64)
url="https://www.kde.org/"
license=(LGPL)
depends=(kparts)
makedepends=(extra-cmake-modules python3 kdoctools)
conflicts=(kde-baseapps-keditbookmarks)
replaces=(kde-baseapps-keditbookmarks)
provides=(kde-baseapps-keditbookmarks)
options=(docs debug)
groups=(kde kde-uninstall kde-applications kde-baseapps)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('d236763c985c967f95132d27ec3436cac20eada7b1373b065adcdbb9f749ccb5'
                        'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}