# Include global configuration

pkgname=kcachegrind
pkgver=18.04.3
pkgrel=1
arch=(x86_64)
pkgdesc="KDE profiler visualization"
screenshot="http://www.kde.org/images/screenshots/kcachegrind.png"
groups=(kde-applications kdesdk)
depends=(kio hicolor-icon-theme)
makedepends=(extra-cmake-modules kdoctools python3 qt5-tools)
license=('GPL' 'LGPL' 'FDL')
options=('docs' 'debug')
conflicts=(kdesdk-kcachegrind)
replaces=(kdesdk-kcachegrind)
provides=(kdesdk-kcachegrind)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('2370827f8d3c29ec931fc3ebf34726e42d25aaaab6c2f10dc5dd87f57056acfd'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}