# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=network
pkgname=haskell-network
pkgver=2.4.1.2
pkgrel=2
pkgdesc="Low-level networking interface"
url="http://hackage.haskell.org/package/network"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=()
depends=('ghc=7.6.3-1' 'haskell-base>=3' 'haskell-base<5' 'haskell-bytestring' 'haskell-parsec>=3.0')
options=('strip')
source=("http://hackage.haskell.org/packages/archive/network/2.4.1.2/network-2.4.1.2.tar.gz")
install="haskell-network.install"
sha512sums=('a9a0237477fbb484ff8a66121a7808e35d4df68552c18cead1f96243f945e9517583f39c769c3ecbd643ec86a253bb3cba638ffb780feb503d60595ad7c4c7f5')

build() {
    cd "${srcdir}/network-2.4.1.2"
    runhaskell Setup configure \
        -O \
        ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } \
        --enable-split-objs \
        --enable-shared \
        --prefix="/usr" \
        --docdir="/usr/share/doc/haskell-network" \
        --libsubdir='$compiler/site-local/$pkgid'
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/network-2.4.1.2"
    install -D -m744 register.sh \
        "${pkgdir}/usr/share/haskell/haskell-network/register.sh"
    install -m744 unregister.sh \
        "${pkgdir}/usr/share/haskell/haskell-network/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/haskell-network/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/network"

    # License
    install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/haskell-network/LICENSE"
    rm -f "${pkgdir}/usr/share/doc/haskell-network/LICENSE"

    runhaskell Setup copy --destdir="${pkgdir}"
}