# Contributions from Arch: https://projects.archlinux.org/svntogit/community.git/tree/trunk?h=packages/bitcoin

pkgbase=bitcoin
pkgname=('bitcoin-daemon' 'bitcoin-cli' 'bitcoin-qt')
pkgver=0.13.1
pkgrel=1
arch=('x86_64')
url="http://www.bitcoin.org/"
makedepends=('boost' 'qrencode' 'miniupnpc' 'protobuf' 'qt5-tools' 'libevent')
license=('MIT')
source=(http://bitcoin.org/bin/bitcoin-core-$pkgver/bitcoin-$pkgver.tar.gz
	https://raw.github.com/bitcoin/bitcoin/v$pkgver/contrib/debian/bitcoin-qt.desktop
	https://raw.github.com/bitcoin/bitcoin/v$pkgver/share/pixmaps/bitcoin128.png
	https://raw.github.com/bitcoin/bitcoin/v$pkgver/contrib/debian/examples/bitcoin.conf
	https://raw.github.com/bitcoin/bitcoin/v$pkgver/contrib/debian/manpages/bitcoind.1
	https://raw.github.com/bitcoin/bitcoin/v$pkgver/contrib/debian/manpages/bitcoin.conf.5)
sha1sums=('729ccb5615c4830eba38f79d0d05bb95ee4909b3'
          '5d9b2f69071dd87923dbebebdabd4ddbfa80ac19'
          '5e5faf2bd4b598a971946e527bca961f17591976'
          '6a53aa6624122ce2fda05c2f152cbae59eef6740'
          '8d51447f993f438a8b32fa42c5c4ef3d01f3f8fe'
          '9ace6f3d4e781f2d16840145eb80571afd5e9c59')

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  ./configure --prefix=/usr \
              --with-incompatible-bdb \
              --enable-hardening \
              --with-gui=qt5
  make
}

package_bitcoin-qt() {
  pkgdesc="Bitcoin is a peer-to-peer network based digital currency - Qt"
  depends=('boost-libs' 'qt5-base' 'miniupnpc' 'qrencode' 'protobuf')
  install=bitcoin-qt.install
  provides=('bitcoin')
  conflicts=('bitcoin')
  replaces=('bitcoin')
  
  cd "$pkgbase-$pkgver"
  install -Dm755 src/qt/bitcoin-qt "$pkgdir"/usr/bin/bitcoin-qt
  install -Dm644 "$srcdir"/bitcoin-qt.desktop \
    "$pkgdir"/usr/share/applications/bitcoin.desktop
  install -Dm644 "$srcdir"/bitcoin128.png \
    "$pkgdir"/usr/share/pixmaps/bitcoin128.png

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}

package_bitcoin-daemon() {
  pkgdesc="Bitcoin is a peer-to-peer network based digital currency - daemon"
  depends=('boost-libs' 'miniupnpc' 'libevent')

  cd "$pkgbase-$pkgver"
  install -Dm755 src/bitcoind "$pkgdir"/usr/bin/bitcoind
  install -Dm644 "$srcdir"/bitcoin.conf \
    "$pkgdir/usr/share/doc/$pkgname/examples/bitcoin.conf"
  install -Dm644 "$srcdir"/bitcoind.1 \
    "$pkgdir"/usr/share/man/man1/bitcoind.1
  install -Dm644 "$srcdir"/bitcoin.conf.5 \
    "$pkgdir"/usr/share/man/man5/bitcoin.conf.5
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}

package_bitcoin-cli() {
  pkgdesc="Bitcoin is a peer-to-peer network based digital currency - RPC client"
  depends=('boost-libs' 'libevent')

  cd "$pkgbase-$pkgver"
  install -Dm755 src/bitcoin-cli "$pkgdir"/usr/bin/bitcoin-cli
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}