# Maintainer: Manuel 'UtG' <utg[dot]chakra.linux[at]gmail[dot]com>

pkgname=qtcreator
pkgver=3.1.1
pkgrel=2
pkgdesc="Lightweight, cross-platform integrated development environment."
arch=('x86_64')
url="http://qt.digia.com/"
license=('LGPL')
makedepends=('qt5-private-headers' 'qt5-base' 'git' 'mesa' 'clang')
depends=('qt5-tools' 'qt5-quick1' 'qt5-quickcontrols')
optdepends=('qt-docs: for the integrated Qt documentation'
            'gdb: for the debugger'
            'cmake: for cmake project suppport'
            'ksshaskpass: for ssh support'
            'git: for git support'
            'mercurial: for mercurial support'
            'bzr: for bazaar support'
            'valgrind: for analyze support')
categories=('programming')
screenshot=("http://qt.nokia.com/images/products/qt-creator-breakdown-screenshot")
options=('docs')
source=("http://download.qt-project.org/official_releases/qtcreator/3.1/${pkgver}/qt-creator-opensource-src-${pkgver}.tar.gz"
	'qtcreator.desktop')
#source=("http://ftp.fau.de/qtproject/official_releases/${pkgname}/3.1/${pkgver}/qt-creator-opensource-src-${pkgver}.tar.gz")
md5sums=('1876878c58b3026e0df26fde9393cd91'
         '5aa242e0262fa22f75c3b59d3a4ec198')
install=qtcreator.install
        

build() {
  cd "${srcdir}"
  
  [[ -d build ]] && rm -r build
  mkdir build && cd build

  qmake-qt5 -r "${srcdir}/qt-creator-opensource-src-${pkgver}/qtcreator.pro"
  make
  make docs -j1
}

package() {
  cd "${srcdir}/build"

  make INSTALL_ROOT="${pkgdir}/usr" install
  make INSTALL_ROOT="${pkgdir}/usr/" install_docs

  install -Dm644 "${srcdir}/qtcreator.desktop" \
    "${pkgdir}/usr/share/applications/qtcreator.desktop"
  install -Dm644 "${srcdir}/qt-creator-opensource-src-${pkgver}/LGPL_EXCEPTION.TXT" \
    "${pkgdir}/usr/share/licenses/qtcreator/LGPL_EXCEPTION.TXT"
}