# Maintainer: Francesco Marinucci <franzmari[at]chakra-project[dot]it>
# Arch Maintainer: Firmicus <firmicus āt gmx dōt net>

pkgname=texlive-langcyrillic
pkgver=2013.32509
_revnr=${pkgver#2013.}
pkgrel=1
pkgdesc="TeX Live - Fonts and macro packages to typeset Cyrillic texts"
license=('GPL')
arch=(x86_64)
depends=('texlive-core')
groups=('texlive-lang')
url='http://tug.org/texlive/'
source=("ftp://ftp.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip" "$pkgname.maps")
options=('!emptydirs')
options=(!strip)
install=texlive.install
md5sums=('4916736fe2990218481ef199dc320095'
         'c1e49c9da6302557dff56e8d9d584fa5')

build() {
   cd "$srcdir"
   for p in *.tar.xz; do
	   bsdtar -xf $p
   done
   rm -rf {tlpkg,doc,source} || true
}

package() {
   cd "$srcdir"
   install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${pkgname}_${_revnr}.pkgs
   install -m644 $pkgname.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
   mkdir -p "${pkgdir}/usr/bin"
   ln -s /usr/share/texmf-dist/scripts/texlive/rubibtex.sh "${pkgdir}/usr/bin/rubibtex"
   ln -s /usr/share/texmf-dist/scripts/texlive/rumakeindex.sh "${pkgdir}/usr/bin/rumakeindex"
}