# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/kdegraphics-strigi-analyzer
# Include global configuration
source ../kdeapps.conf

pkgname=kdegraphics-strigi-analyzer
pkgver=${_kdever}
pkgrel=1
pkgdesc='Strigi analyzers for various graphics file formats'
arch=('x86_64')
url='https://projects.kde.org/projects/kde/kdegraphics/kdegraphics-strigi-analyzer'
license=('GPL' 'LGPL' 'FDL')
depends=("kdelibs>=${_libsver}"
         'strigi')
makedepends=('pkg-config' 'cmake' 'automoc4')
groups=('kde' 'kdegraphics' 'kde-uninstall')
options=('docs' '!header' 'debug' 'log')
source=("$_mirror/${pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d" " -f1`)

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    cmake . \
        -DCMAKE_BUILD_TYPE=${_build_type} \
        -DCMAKE_INSTALL_PREFIX=${_installprefix} \
        -DCMAKE_SKIP_RPATH=ON \
        -DKDE4_BUILD_TESTS=ON \
        -DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed'
    make
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    make DESTDIR=${pkgdir} install
}