pkgname=amarok
pkgver=2.9.0
pkgrel=1
pkgdesc="A media player for KDE"
arch=('x86_64')
url="https://amarok.kde.org"
screenshot="http://amarok.kde.org/files/Amarok-2.6-InDulciJubilo-screenie4.png"
license=('GPL2' 'LGPL2.1' 'FDL')
depends=('kde-runtime' 'mariadb' 'qtscriptgenerator' 'taglib-extras' 'liblastfm-qt4' 'ffmpeg' 'libofa'
         'qjson' 'libbluray' 'libmygpo-qt')
makedepends=('pkgconfig' 'automoc4' 'cmake' 'libgpod' 'libmtp' 'docbook-xsl' 'mesa' 'clamz' 'loudmouth')
optdepends=("libgpod: support Apple iPod audio devices"
            "libmtp: support for portable media devices"
            "ifuse: support for Apple iPod Touch and iPhone"
            "clamz: allow to download songs from Amazon.com"
            "loudmouth: backend needed by mp3tunes for syncing")
categories=('multimedia')
install="${pkgname}.install"
source=("https://download.kde.org/stable/${pkgname}/${pkgver}/src/${pkgname}-${pkgver}.tar.xz")
sha256sums=('e3678de79db36956bc8588b9905726ace1b9188e7fdf89eaea265f1cb03116fd')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  mkdir build
  cd build
  cmake .. \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE4_BUILD_TESTS=OFF \
    -DWITH_NepomukCore=OFF \
    -DWITH_Soprano=OFF
  make
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  make DESTDIR="${pkgdir}" install
}