gtk/ibus/PKGBUILD

pkgname=ibus
pkgver=1.5.19
pkgrel=2
pkgdesc="Next Generation Input Bus for Linux, IBus qt library and IBus qt input method plugin included"
arch=('x86_64')
url="https://github.com/ibus/ibus"
license=('LGPL')
depends=('dconf' 'gtk2' 'gtk3' 'hicolor-icon-theme' 'libnotify' 'python3-dbus' 'python3-gobject' 
         'iso-codes' 'python2-gobject2' 'python2-dbus' 'python2-gobject' 'librsvg')
makedepends=('gobject-introspection' 'vala' 'intltool' 'gnome-common' 'gtk-doc' 'gconf' 'qt5-base'
             'unicode-emoji' 'unicode-character-database' 'cldr-emoji-annotation')
options=('!emptydirs')
install=ibus.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/ibus/ibus/archive/$pkgver.tar.gz")
sha1sums=('04be911a8b5b2f0a6148149536ae54a7f1b25ba8')

prepare() {
  cd ${pkgname}-${pkgver}
  sed -i 's|$(libibus) $(libibus_emoji_dialog)|$(libibus_emoji_dialog) $(libibus)|' ui/gtk3/Makefile.am
}

build() {
  cd ${pkgname}-${pkgver}
  ./autogen.sh \
    --prefix=/usr \
    --libexecdir=/usr/lib/ibus \
    --sysconfdir=/etc \
    --disable-gconf \
    --enable-dconf \
    --enable-wayland \
    --enable-gtk-doc \
    --disable-memconf \
    --enable-ui \
    --enable-python-library \
    --with-python=python3 \
    --with-ucd-dir=/usr/share/unicode/
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}