gtk/fcitx-gtk/PKGBUILD

_pkgbase=fcitx
pkgbase=fcitx-gtk
pkgname=('fcitx-gtk2' 'fcitx-gtk3')
pkgver=4.2.9.6
pkgrel=1
pkgdesc="Gtk im module for fcitx"
arch=('x86_64')
url="https://github.com/fcitx/fcitx-gtk"
license=('GPL')
makedepends=('gtk2' 'gtk3' 'cmake' 'icu' 'opencc' 'iso-codes' 'libxkbfile' 'cairo'
             'pango' 'dbus' 'qt' 'extra-cmake-modules' 'lua')
source=(https://download.fcitx-im.org/$_pkgbase/$_pkgbase-${pkgver}_dict.tar.xz)
md5sums=('29e18ea4144c4e059dc2c56fb62d55e5')

prepare() {
    cd ${srcdir}/${_pkgbase}-${pkgver}
    [[ -e build ]] && rm -rf build
    mkdir build
}
build(){
    cd ${srcdir}/${_pkgbase}-${pkgver}/build
    cmake -DENABLE_GTK3_IM_MODULE=ON \
          -DCMAKE_INSTALL_PREFIX=/usr \
	  -DENABLE_LUA=On \
	  -DENABLE_GIR=Off \
          -DCMAKE_BUILD_TYPE=Release ..
    make
}

package_fcitx-gtk2 ()
{
    pkgdesc='GTK2 IM Module for fcitx'
    depends=('gtk2' "fcitx>=$pkgver")
    install="fcitx-gtk2.install"
    cd "${srcdir}/${_pkgbase}-${pkgver}/build/src/frontend/gtk2"
    make DESTDIR=${pkgdir} install
}

package_fcitx-gtk3 ()
{
    pkgdesc='GTK3 IM Module for fcitx'
    depends=('gtk3' "fcitx>=$pkgver")
    install="fcitx-gtk3.install"
    cd "${srcdir}/${_pkgbase}-${pkgver}/build/src/frontend/gtk3"
    make DESTDIR=${pkgdir} install
}