gtk/thunderbird/PKGBUILD

pkgname=thunderbird
pkgver=17.0.7
pkgrel=1
pkgdesc="Standalone Mail/News reader"
arch=('x86_64')
license=('MPL' 'GPL')
url="http://www.mozilla.org/thunderbird/"
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libnotify' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite3' 'startup-notification' 'filesystem-extra')
makedepends=('unzip' 'zip' 'pkg-config' 'python2' 'wireless_tools' 'yasm' 'mesa' 'autoconf2.13')
optdepends=('thunderbird-i18n: for multilanguage support'
	    'libcanberra: for sound support')
install=thunderbird.install
source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
        mozconfig
        thunderbird.desktop
        thunderbird-install-dir.patch
        vendor.js)
options=(!emptydirs)
md5sums=('31f07c3911d1d6772831195af64db963'
         '2e6dfd672d63a72d1e2fe1f9b91807e6'
         'af3e5b344d2edf1c7d61bb0a5a96de9a'
         '1c6f47b315a5d7830f8e901b1f723cfc'
         '5a53179d14ae9631b7afe5e4d0fc0b25')

build() {
  cd comm-esr17
  patch -Np1 -i "$srcdir/thunderbird-install-dir.patch"

  cp "$srcdir/mozconfig" .mozconfig

  # configure script misdetects the preprocessor without an optimization level
  # https://bugs.archlinux.org/task/34644
  sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' configure

  export LDFLAGS="$LDFLAGS -Wl,-rpath,/extra/usr/lib/thunderbird"
  export PYTHON="/usr/bin/python2"

  make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
}

package() {
  cd comm-esr17
  make -j1 -f client.mk DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir"/vendor.js "$pkgdir/extra/usr/lib/thunderbird/defaults/preferences/vendor.js"

  for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
      install -Dm644 other-licenses/branding/thunderbird/mailicon${i/x*/}.png \
          "$pkgdir/extra/usr/share/icons/hicolor/$i/apps/thunderbird.png"
  done

  install -Dm644 "$srcdir/thunderbird.desktop" \
      "$pkgdir/extra/usr/share/applications/thunderbird.desktop"

  rm -rf "$pkgdir"/extra/usr/lib/thunderbird/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "$pkgdir/extra/usr/lib/thunderbird/dictionaries"
  ln -sf /usr/share/hyphen "$pkgdir/extra/usr/lib/thunderbird/hyphenation"
  
  # We don't want the development stuff
  rm -r "$pkgdir"/extra/usr/{include,lib/thunderbird-devel,share/idl}
}