gtk/thunderbird-kde/PKGBUILD

# Maintainer:  AlmAck <almack@chakra-project.org>

pkgname=thunderbird-kde
pkgver=24.6.0
pkgrel=1
provides=(thunderbird=${pkgver})
conficts=(thunderbird)
replaces=(thunderbird)
pkgdesc="Standalone Mail/News reader"
arch=('x86_64')
license=('MPL' 'GPL')
url="http://www.mozilla.org/thunderbird/"
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite3' 'startup-notification' 'nspr' 'kdelibs')
makedepends=('unzip' 'zip' 'pkg-config' 'python2' 'wireless_tools' 'yasm' 'mesa' 'autoconf2.13' 
             'gstreamer0.10-base-plugins' 'xorg-server')
optdepends=('thunderbird-i18n: for multilanguage support'
	    'libcanberra: for sound support')
install=thunderbird.install
# For patch look here: https://build.opensuse.org/package/show?project=openSUSE:Factory&package=MozillaThunderbird
source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
        mozconfig
        thunderbird.desktop
        thunderbird-install-dir.patch
        mozilla-kde.patch
        mozilla-nongnome-proxies.patch
        vendor.js
        kde.js)
options=(!emptydirs)
md5sums=('3e5d44c7e716e132601a40e865a13ef8'
         '1d674019505aa9ec1654cba08debf61d'
         'af3e5b344d2edf1c7d61bb0a5a96de9a'
         '1c6f47b315a5d7830f8e901b1f723cfc'
         '1aa96187c06a79785c4aec590baa4428'
         '28f61de31540e20522aefdbe88a83fa8'
         '5a53179d14ae9631b7afe5e4d0fc0b25'
         '75df0f88cc7a7fa7d522459e4ff82cc5')

prepare(){
  cd comm-esr24
  patch -Np1 -i "$srcdir/thunderbird-install-dir.patch"
  
  pushd mozilla
  patch -Np1 -i "$srcdir/mozilla-nongnome-proxies.patch"
  patch -Np1 -i "$srcdir/mozilla-kde.patch"
  popd
  
  cp "$srcdir/mozconfig" .mozconfig

  # configure script misdetects the preprocessor without an optimization level
  # https://bugs.archlinux.org/task/34644
  sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' mozilla/configure
}
         
build() {
  cd comm-esr24  
  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/thunderbird"
  export PYTHON="/usr/bin/python2"

  # Normal Build
  #make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
  
  # Set up PGO
  export DISPLAY=:99
  Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 $DISPLAY &

  # Build
  if ! make -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS" MOZ_PGO=1; then
    kill $!
    return 1
  fi

  # Kill leftovers
  kill $! || true
}

package() {
  cd comm-esr24
  make -f client.mk DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir"/vendor.js "$pkgdir/usr/lib/thunderbird/defaults/preferences/vendor.js"
  install -Dm644 "$srcdir"/kde.js "$pkgdir/usr/lib/thunderbird/defaults/preferences/kde.js"

  for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
      install -Dm644 other-licenses/branding/thunderbird/mailicon${i/x*/}.png \
          "$pkgdir/usr/share/icons/hicolor/$i/apps/thunderbird.png"
  done

  install -Dm644 "$srcdir/thunderbird.desktop" \
      "$pkgdir/usr/share/applications/thunderbird.desktop"

  rm -rf "$pkgdir"/usr/lib/thunderbird/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "$pkgdir/usr/lib/thunderbird/dictionaries"
  ln -sf /usr/share/hyphen "$pkgdir/usr/lib/thunderbird/hyphenation"
  
  # We don't want the development stuff
  #rm -r "$pkgdir"/usr/{include,lib/thunderbird-devel,share/idl}
}