gnome-keyring: imported in [gtk] as dependency of skype

gnome-keyring/PKGBUILD

@@ -0,0 +1,41 @@
+# Contributions from ArchLinux: https://git.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/gnome-keyring
+
+pkgname=gnome-keyring
+pkgver=3.20.0+57+g9db67ef
+pkgrel=1
+pkgdesc="Stores passwords and encryption keys"
+url="https://wiki.gnome.org/Projects/GnomeKeyring"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gcr libcap-ng pam)
+makedepends=(intltool gtk-doc gnome-common git python3)
+install=gnome-keyring.install
+_commit=9db67ef6e39ac51d426dee91da3b9305670241e6  # master
+source=("git+https://git.gnome.org/browse/gnome-keyring#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd "$pkgname"
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --libexecdir=/usr/lib/gnome-keyring \
+      --with-pam-dir=/usr/lib/security --with-root-certs=/etc/ssl/certs \
+      --disable-schemas-compile
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd "$pkgname"
+  make DESTDIR="$pkgdir" install
+}

gnome-keyring/gnome-keyring.install

@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_ipc_lock=ep usr/bin/gnome-keyring-daemon
+}
+
+post_upgrade() {
+  post_install
+}