[staging] update gtkmm

gtkmm/PKGBUILD

@@ -1,27 +1,48 @@
 pkgbase=gtkmm
-pkgname=('gtkmm')
-pkgver=2.24.4
-pkgrel=2
-pkgdesc="C++ bindings for gtk2"
-arch=('x86_64')
-depends=('gtk2' 'pangomm' 'atkmm')
-license=('LGPL')
-options=('!emptydirs')
-url="http://gtkmm.sourceforge.net/"
-install=install
-source=("http://ftp.gnome.org/pub/GNOME/sources/${pkgbase}/2.24/${pkgbase}-${pkgver}.tar.xz")
-md5sums=('b9ac60c90959a71095f07f84dd39961d')
+pkgname=(gtkmm gtkmm-docs)
+pkgver=2.24.5+6+g85967ecc
+pkgrel=1
+pkgdesc="C++ bindings for GTK+ 2"
+url="http://www.gtkmm.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gtk2 pangomm atkmm)
+makedepends=(git mm-common glibmm-docs cairomm-docs pangomm-docs atkmm-docs)
+_commit=85967ecc93d16892896626dfac54143b16ba9b9c  # gtkmm-2-24
+source=("git+https://git.gnome.org/browse/gtkmm#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+  NOCONFIGURE=1 ./autogen.sh
+}
 
 build() {
-  cd "${srcdir}/${pkgbase}-${pkgver}"
-  ./configure --prefix=/usr --disable-documentation
+  cd $pkgbase
+
+  # glibmm 2.46 uses C++11 features
+  CXXFLAGS+=' -std=c++11'
+
+  ./configure --prefix=/usr --enable-maintainer-mode
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
   make
 }
 
-package() {
-  cd "${srcdir}/${pkgbase}-${pkgver}"
-
+package_gtkmm() {
+  cd $pkgbase
   sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
-
-  make DESTDIR="${pkgdir}" install
+  make DESTDIR="$pkgdir" install
+}
+
+package_gtkmm-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  cd $pkgbase
+  make -C docs DESTDIR="$pkgdir" install
 }