pkgname=thunderbird-i18n
pkgver=31.7.0
pkgrel=1
pkgdesc="Language pack for Thunderbird"
arch=('any')
url="http://www.mozilla.com/"
license=('MPL' 'GPL')
depends=("thunderbird-kde>=$pkgver")

_languages=(
  'ar     "Arabic"'
  'ast    "Asturian"'
  'be     "Belarusian"'
  'bg     "Bulgarian"'
  'bn-BD  "Bengali (Bangladesh)"'
  'br     "Breton"'
  'ca     "Catalan"'
  'cs     "Czech"'
  'da     "Danish"'
  'de     "German"'
  'el     "Greek"'
  'en-GB  "English (British)"'
  'en-US  "English (US)"'
  'es-AR  "Spanish (Argentina)"'
  'es-ES  "Spanish (Spain)"'
  'et     "Estonian"'
  'eu     "Basque"'
  'fi     "Finnish"'
  'fr     "French"'
  'fy-NL  "Frisian"'
  'ga-IE  "Irish"'
  'gd     "Gaelic (Scotland)"'
  'gl     "Galician"'
  'he     "Hebrew"'
  'hr     "Croatian"'
  'hu     "Hungarian"'
  'hy-AM  "Armenian"'
  'id     "Indonesian"'
  'is     "Icelandic"'
  'it     "Italian"'
  'ja     "Japanese"'
  'ko     "Korean"'
  'lt     "Lithuanian"'
  'nb-NO  "Norwegian (Bokmål)"'
  'nl     "Dutch"'
  'nn-NO  "Norwegian (Nynorsk)"'
  'pa-IN  "Punjabi"'
  'pl     "Polish"'
  'pt-BR  "Portuguese (Brazilian)"'
  'pt-PT  "Portuguese (Portugal)"'
  'rm     "Romansh"'
  'ro     "Romanian"'
  'ru     "Russian"'
  'si     "Sinhala"'
  'sk     "Slovak"'
  'sl     "Slovenian"'
  'sq     "Albanian"'
  'sr     "Serbian"'
  'sv-SE  "Swedish"'
  'ta-LK  "Tamil (Sri Lanka)"'
  'tr     "Turkish"'
  'uk     "Ukrainian"'
  'vi     "Vietnamese"'
  'zh-CN  "Chinese (Simplified)"'
  'zh-TW  "Chinese (Traditional)"'
)
md5sums=('fc43969833431a60229b219fbdc474fd'
         'bd57da593956b3f77a958d9aaffb6253'
         '10c330fe30677b76920f159923499dab'
         '8cb00e523ccc1549e62ebbcff28ea32d'
         'fa0eb0ff2e3908d5ad8bc29366c861fa'
         '69961de5994c9ccca6edaedd8879f5e1'
         '530b69313efbbe0216fd697bd0e34def'
         '9360bf9ba2d0233c2776c3135225ace8'
         'f00cd30fac89f3eca7e1c543a0058465'
         '1e4cd8684acbc5d5f4dcdd9069bbdb46'
         '7a150122ed9788e79ee76c4ebf6f03c5'
         '903f00f643421661f836271a304163b0'
         '19dc85a4e0dbb77b1d300d6a6172675f'
         'fb7c9d476617ba8777029e914ee3e42f'
         '6e28d725575ec94e77105546274ba34c'
         'e7485db50fd92692bacf05aed626f747'
         'b41f221c358db0a863cb6072f5962833'
         '85e2e87d6515e088a4235ae87feb7d92'
         '3303c37898edd11bb52e16479ef22546'
         'fd17bc01adb73a966fa8baad66adcc61'
         '7b1793729f360db59a6da6fc238e3118'
         '0cbd8932ba0b9149d8e23e3d5ac28064'
         '97c8dac1ad5c42db3911be46b08a51f7'
         '19968a05618d7149e8d4bfd4e70eb923'
         'd4a08f6077a429121781ec537e6758e3'
         '4aaa01a0af76a55c88f70f11f3e8598e'
         '16dfdb2ab0100d8bc7fde8e754146b4a'
         '27c7b0cdd8ecbca97bfc8d481c4fa596'
         'f5681fd15d539d22c824587beb1cb67b'
         '7ed732b6021cc201fee02d40cf3fbdc1'
         '4faadaec41a061695a7f1b9368cc9c26'
         '7fd6c7a22bdcd50d2f6e199c1d926a2f'
         '50f26d533f1aac0743831da63f2fcaa1'
         'baf89064c6f4ed854de0a3936fe67755'
         '4c580c208dc5b833ff53b22a5ffaa054'
         '9648978bfda56497fee23bdfd036d1af'
         '88cf26e0ad238eed810ee9697baf3849'
         'd35bc4f578acb29717be13aedb92ee0c'
         '3044b0a5a435dfdd772baf40efae3774'
         'f6feb2e38f34247267e1b7f6422b85ed'
         '6a8d86da489cca359686e262d29e1feb'
         'ec8d6ac29e88d2bdd7f03416aad23aa1'
         '15027bf84efaeee9b4d59e6225ca6873'
         '72d24203e5f6dc5619fafe7a307bdd70'
         '62890c671d6e0911e3c05a5c7cee97df'
         '720e3930bf584f3c5b782357b9a0d993'
         '46287d32fa4f9295cc9b8dfcf88cbb19'
         'cae9a77d7ca0b933aa6068cffed4d9e1'
         '3aa2e5313d9eb9c67b24cdbc4951ac79'
         'bdd6786e9fd73498e1aa2d5177ee4da2'
         'a1788bcd63f8575518e3fff6da44efc9'
         '6e3bb4e0b59ed8506eb9714498e8c4ac'
         '361fc7c925fff3b66b2dbbcc66485679'
         '1c86822c7e4cddc8bda9813561e67c2a'
         '1277975dd99f303059e0a4a4f52b725d')


pkgname=('thunderbird-i18n')
source=()
_url=https://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/linux-x86_64/xpi

for _lang in "${_languages[@]}"; do
  _locale=${_lang%% *}
  _pkgname=thunderbird-i18n-${_locale,,}

  pkgname+=($_pkgname)
  source+=("thunderbird-i18n-$pkgver-$_locale.xpi::$_url/$_locale.xpi")
  eval "package_$_pkgname() {
    _package $_lang
  }"
done

# Don't extract anything
noextract=(${source[@]%%::*})

package_thunderbird-i18n() {
  pkgdesc="Transition package to split build"
  depends=("thunderbird-kde=${pkgver}" "thunderbird-langpack=${pkgver}")
}

_package() {
  pkgdesc="$2 language pack for Thunderbird"
  provides=("thunderbird-langpack=${pkgver}")
  conflicts=("thunderbird-i18n<31.0")
  install -Dm644 thunderbird-i18n-$pkgver-$1.xpi \
    "$pkgdir/usr/lib/thunderbird/extensions/langpack-$1@thunderbird.mozilla.org.xpi"
}