lib32/lib32-catalyst-utils/PKGBUILD

# Lib32 Packages for Chakra, part of chakra-project.org

pkgname=(lib32-catalyst-utils 'lib32-catalyst-libgl' 'lib32-opencl-catalyst')
pkgver=14.9
pkgrel=2
_amdver=14.201
url="http://www.amd.com"
pkgdesc="AMD/ATI catalyst driver utilities and libraries. (32-bit)"
arch=(x86_64)
license=('custom')
options=('staticlibs' 'libtool' '!strip' '!upx')
source=(
#    http://www2.ati.com/drivers/linux/amd-catalyst-${pkgver/./-}-rev2-linux-x86-x86-64-may6.zip
    http://archive.ubuntu.com/ubuntu/pool/restricted/f/fglrx-installer/fglrx-installer_14.201.orig.tar.gz
        "lib32-catalyst.sh")
md5sums=('ff3a7604051971de617a5f4703826ec6'
         'af7fb8ee4fc96fd54c5b483e33dc71c4')

build() {
  ## Unpack archive
#      /bin/sh ./amd-catalyst-${pkgver}-linux-x86.x86_64.run --extract archive_files
#     /bin/sh ./fglrx-${_amdver}/amd-driver-installer-${_amdver}-x86.x86_64.run --extract archive_files
mkdir common
mv etc lib usr common
mkdir archive_files
mv arch common xpic xpic_64a archive_files
}

package_lib32-catalyst-libgl() {
      pkgdesc="AMD/ATI drivers. Catalyst drivers libraries symlinks (32-bit)"
      depends=(lib32-catalyst-utils=$pkgver 'lib32-mesa')
      conflicts=('lib32-libgl')
      provides=('lib32-libgl')

      install -dm755 ${pkgdir}/usr/lib32/fglrx
      ln -sf /usr/lib32/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/fglrx/libGL.so.1.2.0
      ln -sf /usr/lib32/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/fglrx/libGL.so.1
      ln -sf /usr/lib32/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/fglrx/libGL.so
      ln -sf /usr/lib32/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/libGL.so.1.2.0
      ln -sf /usr/lib32/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/libGL.so.1
      ln -sf /usr/lib32/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/libGL.so


    # We have to provide symlinks to lib32-mesa, as catalyst doesn't ship them
      ln -s /usr/lib32/mesa/libEGL.so.1.0.0 ${pkgdir}/usr/lib32/libEGL.so.1.0.0
      ln -s libEGL.so.1.0.0	                ${pkgdir}/usr/lib32/libEGL.so.1
      ln -s libEGL.so.1.0.0                 ${pkgdir}/usr/lib32/libEGL.so

      ln -s /usr/lib32/mesa/libGLESv1_CM.so.1.1.0 ${pkgdir}/usr/lib32/libGLESv1_CM.so.1.1.0
      ln -s libGLESv1_CM.so.1.1.0	              ${pkgdir}/usr/lib32/libGLESv1_CM.so.1
      ln -s libGLESv1_CM.so.1.1.0                 ${pkgdir}/usr/lib32/libGLESv1_CM.so

      ln -s /usr/lib32/mesa/libGLESv2.so.2.0.0 ${pkgdir}/usr/lib32/libGLESv2.so.2.0.0
      ln -s libGLESv2.so.2.0.0                 ${pkgdir}/usr/lib32/libGLESv2.so.2
      ln -s libGLESv2.so.2.0.0                 ${pkgdir}/usr/lib32/libGLESv2.so


     # License
      install -m755 -d ${pkgdir}/usr/share/licenses
      ln -s $_pkgbasename ${pkgdir}/usr/share/licenses/${pkgname}
}

package_lib32-opencl-catalyst() {
      pkgdesc="AMD/ATI drivers. OpenCL implemention for AMD Catalyst (32-bit)"
      provides=('lib32-libcl')
      conflicts=('lib32-libcl')
      depends=('lib32-gcc-libs')
      optdepends=('opencl-headers: headers necessary for OpenCL development')

      install -m755 -d ${pkgdir}/etc/OpenCL/vendors
      install -m644 ${srcdir}/archive_files/arch/x86/etc/OpenCL/vendors/amdocl32.icd ${pkgdir}/etc/OpenCL/vendors

      cd ${srcdir}/archive_files/arch/x86
      install -m755 -d ${pkgdir}/usr/lib32
      install -m755 usr/lib/libamdocl*.so ${pkgdir}/usr/lib32
      install -m755 usr/lib/libOpenCL.so.1 ${pkgdir}/usr/lib32
      ln -s libOpenCL.so.1 ${pkgdir}/usr/lib32/libOpenCL.so

     # License
      install -m755 -d ${pkgdir}/usr/share/licenses
      ln -s $_pkgbasename ${pkgdir}/usr/share/licenses/${pkgname}
}

package_lib32-catalyst-utils() {
      pkgdesc="AMD/ATI drivers. Utilities and libraries (32-bit)"
      depends=('lib32-libxext' 'lib32-libdrm' 'catalyst-utils' 'lib32-libxinerama')
      conflicts=('lib32-catalyst-utils-pxp')
      provides=('lib32-dri' 'lib32-libtxc_dxtn')
      optdepends=('lib32-catalyst-libgl: Catalyst drivers libraries symlinks (32-bit)'
		  'lib32-opencl-catalyst: OpenCL implemention for AMD Catalyst (32-bit)')
      install=${pkgname}.install

      cd ${srcdir}
      install -D -m755 lib32-catalyst.sh ${pkgdir}/etc/profile.d/lib32-catalyst.sh
      cd ${srcdir}/archive_files/arch/x86/usr
      install -dm755 ${pkgdir}/usr/lib32/fglrx
#       install -dm755 ${pkgdir}/usr/lib32/hsa
      install -dm755 ${pkgdir}/usr/lib32/xorg/modules/dri
      install -m755 lib/*.so* ${pkgdir}/usr/lib32
#       install -m755 lib/hsa/* ${pkgdir}/usr/lib32/hsa
      install -m755 X11R6/lib/fglrx/fglrx-libGL.so.1.2 ${pkgdir}/usr/lib32/fglrx
      install -m755 X11R6/lib/libAMDXvBA.so.1.0 ${pkgdir}/usr/lib32
      install -m755 X11R6/lib/libatiadlxx.so ${pkgdir}/usr/lib32
      install -m755 X11R6/lib/libfglrx_dm.so.1.0 ${pkgdir}/usr/lib32
      install -m755 X11R6/lib/libXvBAW.so.1.0 ${pkgdir}/usr/lib32
      install -m755 X11R6/lib/modules/dri/*.so ${pkgdir}/usr/lib32/xorg/modules/dri
      ln -snf /usr/lib32/xorg/modules/dri ${pkgdir}/usr/lib32/dri

      ln -sf /usr/lib32/libfglrx_dm.so.1.0	${pkgdir}/usr/lib32/libfglrx_dm.so.1
      ln -sf /usr/lib32/libfglrx_dm.so.1.0	${pkgdir}/usr/lib32/libfglrx_dm.so
      ln -sf /usr/lib32/libAMDXvBA.so.1.0	${pkgdir}/usr/lib32/libAMDXvBA.so.1
      ln -sf /usr/lib32/libAMDXvBA.so.1.0	${pkgdir}/usr/lib32/libAMDXvBA.so
      ln -sf /usr/lib32/libXvBAW.so.1.0		${pkgdir}/usr/lib32/libXvBAW.so.1
      ln -sf /usr/lib32/libXvBAW.so.1.0		${pkgdir}/usr/lib32/libXvBAW.so
      ln -sf /usr/lib32/libatiuki.so.1.0	${pkgdir}/usr/lib32/libatiuki.so.1
      ln -sf /usr/lib32/libatiuki.so.1.0	${pkgdir}/usr/lib32/libatiuki.so

     # provided in lib32-opencl-catalyst package
      rm ${pkgdir}/usr/lib32/lib{amdocl*,OpenCL}.so*

     # License
      install -m755 -d ${pkgdir}/usr/share/licenses
      ln -s $_pkgbasename ${pkgdir}/usr/share/licenses/${pkgname}
}