lib32/lib32-p11-kit/PKGBUILD

# $Id$
# Maintainer: Florian Pritz <bluewind@xinu.at>
# Contributor: Christoph Vigano <mail@cvigano.de>

_pkgbasename=p11-kit
pkgname=lib32-$_pkgbasename
pkgver=0.23.1
pkgrel=1
pkgdesc="Library to work with PKCS#11 modules (32-bit)"
arch=(x86_64)
url="http://p11-glue.freedesktop.org"
license=('BSD')
depends=(lib32-glibc lib32-libtasn1 lib32-libffi "$_pkgbasename=${pkgver}")
options=(!libtool)
source=($url/releases/$_pkgbasename-$pkgver.tar.gz{,.sig}
        libnssckbi-compat.patch)
validpgpkeys=(C0F67099B808FB063E2C81117BFB1108D92765AF)
md5sums=('96f073270c489c9a594e1c9413f42db8'
         'SKIP'
         '8c3f119005908cf4a3e0ef0a0a310f14')

prepare() {
  cd "$srcdir/$_pkgbasename-$pkgver"

  # Build and install an additional library (libnssckbi-p11-kit.so) which
  # is a copy of p11-kit-trust.so but uses the same label for root certs as
  # libnssckbi.so ("Builtin Object Token" instead of "Default Trust")
  # https://bugs.freedesktop.org/show_bug.cgi?id=66161
  patch -Np1 -i ../libnssckbi-compat.patch

  autoreconf -vi
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  cd "$srcdir/$_pkgbasename-$pkgver"

  ./configure --prefix=/usr --libdir=/usr/lib32 --sysconfdir=/etc \
    --with-module-path=/usr/lib32/pkcs11 \
    --with-trust-paths=/etc/ca-certificates/trust-source:/usr/share/ca-certificates/trust-source
  make
}

check() {
  cd "$srcdir/$_pkgbasename-$pkgver"
  make check
}

package() {
  cd "$srcdir/$_pkgbasename-$pkgver"
  make DESTDIR="$pkgdir" install
  rm -rf "${pkgdir}"/etc
  rm -rf "${pkgdir}"/usr/{bin,include,share}
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING

  ln -srf "$pkgdir/usr/bin/update-ca-trust" "$pkgdir/usr/lib32/p11-kit/trust-extract-compat"
}

# vim:set ts=2 sw=2 et: