lib32/lib32-harfbuzz/PKGBUILD

# Lib32 packages for Chakra

_pkgbasename=harfbuzz
pkgname=lib32-$_pkgbasename
pkgver=0.9.21
pkgrel=1
pkgdesc="OpenType text shaping engine. (32-bit)"
arch=('i686' 'x86_64')
url="http://www.freedesktop.org/wiki/Software/HarfBuzz"
license=('MIT')
depends=('lib32-icu' 'lib32-glib2' 'lib32-freetype2' $_pkgbasename=$pkgver)
makedepends=('gcc-multilib' 'lib32-cairo')
options=(!libtool)
source=(http://www.freedesktop.org/software/harfbuzz/release/${_pkgbasename}-${pkgver}.tar.bz2)
sha256sums=('a0d36f883d98f2375f9b2a03c8a6c361b161a76d4b58ea9d08be59e39e73dae8')

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "${srcdir}/${_pkgbasename}-${pkgver}"

  #autoreconf --force --install --verbose
  ./configure --prefix=/usr \
              --libdir=/usr/lib32 \
              --with-glib \
	      --with-freetype \
	      --with-cairo \
	      --with-icu \
              --without-graphite2
  make
}

package() {
  cd "${srcdir}/${_pkgbasename}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/{include,share,bin}
  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}