lib32/lib32-curl/PKGBUILD

pkgname=lib32-curl
_pkgname=curl
pkgver=7.59.0
pkgrel=1
pkgdesc="An URL retrieval utility and library (32-bit)"
arch=('x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('lib32-libssh2' 'lib32-krb5' 'lib32-libidn' "${_pkgname}=${pkgver}")
makedepends=('lib32-gcc-libs')
source=("http://curl.haxx.se/download/$_pkgname-$pkgver.tar.bz2")
md5sums=('a2192804f7c2636a09320416afcf888e')

build() {
  cd "$_pkgname-$pkgver"

  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  ./configure \
      --prefix=/usr \
      --mandir=/usr/share/man \
      --libdir=/usr/lib32 \
      --disable-dependency-tracking \
      --disable-ldap \
      --disable-ldaps \
      --enable-ipv6 \
      --enable-manual \
      --enable-versioned-symbols \
      --enable-threaded-resolver \
      --with-gssapi \
      --with-libidn \
      --with-random=/dev/urandom \
      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt

  make
}

package() {
  cd "$_pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  rm -rf "${pkgdir}"/usr/{share,bin,include}
  
  # license
  install -d "$pkgdir/usr/share/licenses"
  ln -s "$_pkgname" "$pkgdir/usr/share/licenses/$pkgname"
}