lib32/lib32-libdrm/PKGBUILD

# Maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
# Contributor (x86_64): AlmAck <almack@chakraos.org>

_pkgbasename=libdrm
pkgname=lib32-$_pkgbasename
pkgver=2.4.58
pkgrel=1
pkgdesc="Userspace interface to kernel DRM services (32-bit)"
arch=(x86_64)
license=('custom')
depends=('lib32-libpciaccess' 'lib32-glibc' $_pkgbasename=$pkgver)
makedepends=(gcc-multilib)
checkdepends=('lib32-cairo')
url="http://dri.freedesktop.org/"
source=(http://dri.freedesktop.org/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2)
sha256sums=('b155fae6b9c9a3b02ef8b77f58c7c219194c996a4018dc55ba66c03996a365dd')

build() {
  cd "${srcdir}/${_pkgbasename}-${pkgver}"

  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  # pthread is useless in Linux
  sed -i "/pthread-stubs/d" configure.ac
  autoreconf --force --install

  ./configure --prefix=/usr --libdir=/usr/lib32 \
      --enable-udev 

  make
}

package() {
  cd "${srcdir}/${_pkgbasename}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/{include,share,bin}
  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}