lib32/lib32-glibc/PKGBUILD

# toolchain build order: 
# lib32-glibc > binutils-multilib > gcc-multilib > binutils-multilib > lib32-glibc

_pkgbasename=glibc
pkgname=lib32-$_pkgbasename
pkgver=2.24
pkgrel=1
_commit=fdfc9260
pkgdesc="GNU C Library (32-bit)"
arch=('x86_64')
url="http://www.gnu.org/software/libc"
license=('GPL' 'LGPL')
depends=($_pkgbasename=$pkgver)
makedepends=('gcc>=5.2' 'git' 'lib32-gcc-libs')
options=('!strip' 'staticlibs' '!emptydirs')
source=(git://sourceware.org/git/glibc.git#commit=${_commit}
        lib32-glibc.conf)
md5sums=('SKIP'
         '6e052f1cb693d5d3203f50f9d4e8c33b')
validpgpkeys=('F37CDAB708E65EA183FD1AF625EF0A436C2A4AFF')  # Carlos O'Donell

prepare() {
  cd ${srcdir}/glibc
  mkdir ${srcdir}/glibc-build
}

build() {
  cd ${srcdir}/glibc-build

  echo "slibdir=/usr/lib32" >> configparms
  echo "rtlddir=/usr/lib32" >> configparms
  echo "sbindir=/usr/sbin" >> configparms
  echo "rootsbindir=/usr/sbin" >> configparms

  #export CFLAGS="${CFLAGS} -mno-tls-direct-seg-refs"
  export CC="gcc -m32"
  export CXX="g++ -m32"

  # remove hardening options for building libraries
  CFLAGS=${CFLAGS/-fstack-protector-strong/}
  CPPFLAGS=${CPPFLAGS/-D_FORTIFY_SOURCE=2/}

  ${srcdir}/glibc/configure --prefix=/usr \
      --libdir=/usr/lib32 --libexecdir=/usr/lib32 \
      --with-headers=/usr/include \
      --with-bugurl=https://chakralinux.org/bugtracker \
      --enable-add-ons \
      --enable-kernel=2.6.32 \
      --enable-bind-now --disable-profile \
      --enable-stackguard-randomization \
      --enable-lock-elision \
      --enable-multi-arch \
      --disable-werror \
      i686-unknown-linux-gnu

  # build libraries with hardening disabled
  echo "build-programs=no" >> configparms
  make

  msg "building programs"
  
  # re-enable hardening for programs
  sed -i "/build-programs=/s#no#yes#" configparms
  # ToDo: check why does not compile with this hardening flags enabled
  #echo "CC += -fstack-protector-strong -D_FORTIFY_SOURCE=2" >> configparms
  #echo "CXX += -fstack-protector-strong -D_FORTIFY_SOURCE=2" >> configparms
  make
}

check() {
  cd ${srcdir}/glibc-build

  # remove harding in preparation to run test-suite
  sed -i '/FORTIFY/d' configparms

  # tst-cleanupx4 failure on i686 is "expected"
  make check || true
}

package() {
  cd ${srcdir}/glibc-build
  make install_root=${pkgdir} install

  rm -rf ${pkgdir}/{etc,sbin,usr/{bin,sbin,share},var}

  # We need one 32 bit specific header file
  find ${pkgdir}/usr/include -type f -not -name stubs-32.h -delete


  # Dynamic linker
  install -d -m755 ${pkgdir}/usr/lib
  ln -s ../lib32/ld-linux.so.2 ${pkgdir}/usr/lib/

  # Add lib32 paths to the default library search path
  install -Dm644 "$srcdir/lib32-glibc.conf" "$pkgdir/etc/ld.so.conf.d/lib32-glibc.conf"

  # Symlink /usr/lib32/locale to /usr/lib/locale
  ln -s ../lib/locale "$pkgdir/usr/lib32/locale"

  # remove the static libraries that have a shared counterpart
  # libc, libdl, libm and libpthread are required for toolchain testsuites
  # in addition libcrypt appears widely required
  rm $pkgdir/usr/lib32/lib{anl,BrokenLocale,nsl,resolv,rt,util}.a

  # Do not strip the following files for improved debugging support
  # ("improved" as in not breaking gdb and valgrind...):
  #   ld-${pkgver}.so
  #   libc-${pkgver}.so
  #   libpthread-${pkgver}.so
  #   libthread_db-1.0.so

  cd $pkgdir
  strip $STRIP_BINARIES \
                        \
                        \
                        usr/lib32/getconf/*


  strip $STRIP_STATIC usr/lib32/*.a

  strip $STRIP_SHARED usr/lib32/{libanl,libBrokenLocale,libcidn,libcrypt}-*.so \
                      usr/lib32/libnss_{compat,db,dns,files,hesiod,nis,nisplus}-*.so \
                      usr/lib32/{libdl,libm,libnsl,libresolv,librt,libutil}-*.so \
                      usr/lib32/{libmemusage,libpcprofile,libSegFault}.so \
                      usr/lib32/{audit,gconv}/*.so
}