added lib32-libogg

lib32-libogg/PKGBUILD

@@ -0,0 +1,40 @@
+# Lib32 Packages for Chakra, part of chakra-project.org
+#
+# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
+# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>
+
+_pkgbasename=libogg
+pkgname=lib32-$_pkgbasename
+pkgver=1.1.4
+pkgrel=1
+pkgdesc="Ogg bitstream and framing library (32-bit)"
+arch=('x86_64')
+url="http://www.xiph.org/ogg/"
+license=('BSD')
+depends=('lib32-glibc' $_pkgbasename)
+makedepends=(gcc-multilib)
+options=('!libtool')
+source=(http://downloads.xiph.org/releases/ogg/$_pkgbasename-$pkgver.tar.gz)
+md5sums=('10200ec22543841d9d1c23e0aed4e5e9')
+
+build() {
+    export CC="gcc -m32"
+    export CXX="g++ -m32"
+    export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+    cd $srcdir/${_pkgbasename}-${pkgver}
+    ./configure --prefix=/usr --libdir=/usr/lib32
+    make
+}
+
+package() {
+    cd $srcdir/${_pkgbasename}-${pkgver}
+
+    make DESTDIR=$pkgdir install
+
+    rm -rf "$pkgdir"/usr/{share,bin}
+    find "$pkgdir"/usr/include/ogg -type f -not -name config_types.h -delete
+    mv "$pkgdir"/usr/include/ogg/config_types{,-32}.h
+    mkdir -p "$pkgdir/usr/share/licenses"
+    ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}