added lib32-libcups

lib32-libcups/PKGBUILD

@@ -0,0 +1,40 @@
+# Lib32 Packages for Chakra, part of chakra-project.org
+#
+# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
+# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>
+
+_pkgbasename=libcups
+pkgname=lib32-$_pkgbasename
+pkgver=1.4.5
+pkgrel=1
+pkgdesc="The CUPS Printing System - client libraries (32-bit)"
+arch=('x86_64')
+license=('GPL')
+url="http://www.cups.org/"
+depends=(lib32-glibc $_pkgbasename)
+makedepends=(gcc-multilib)
+source=(http://ftp.easysw.com/pub/cups/${pkgver}/cups-${pkgver}-source.tar.bz2)
+md5sums=('50729f6fc46ba54223e0eaf5009f3419')
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  cd ${srcdir}/cups-${pkgver}
+  
+  aclocal -I config-scripts
+  autoconf -I config-scripts
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+     --disable-ldap --enable-raw-printing --disable-gssapi --disable-dbus \
+     --enable-ssl=no --disable-gnutls --disable-threads \
+     --with-optim="$CFLAGS" --libdir=/usr/lib32
+  make
+}
+
+package() {
+  cd ${srcdir}/cups-${pkgver}
+  make BUILDROOT=${pkgdir} install-libs
+}
+