diff --git a/lib32-keyutils/PKGBUILD b/lib32-keyutils/PKGBUILD
new file mode 100644
index 0000000..550258b
--- /dev/null
+++ b/lib32-keyutils/PKGBUILD
@@ -0,0 +1,35 @@
+# Lib32 Packages for Chakra, part of chakra-project.org
+#
+# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
+# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>
+
+_pkgbasename=keyutils
+pkgname=lib32-$_pkgbasename
+pkgver=1.4
+pkgrel=1
+pkgdesc="Linux Key Management Utilities (32-bit)"
+arch=(x86_64)
+url="http://www.kernel.org"
+license=('GPL2' 'LGPL2.1')
+depends=(lib32-glibc $_pkgbasename)
+makedepends=(gcc-multilib)
+source=(http://people.redhat.com/~dhowells/$_pkgbasename/$_pkgbasename-$pkgver.tar.bz2)
+md5sums=('e168c1bdaf5aa93c2cbf8a5e7f8ef27b')
+
+build() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+  
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  sed -i -e 's/^\(USR\)\?LIBDIR\s*:=.*$/\1LIBDIR=\/usr\/lib32/' Makefile
+  make CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+package() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  rm -rf "${pkgdir}"/{usr/{include,share,bin,sbin},etc,{s,}bin}
+}