added lib32-libssh2

lib32-libssh2/PKGBUILD

@@ -0,0 +1,42 @@
+# Lib32 Packages for Chakra, part of chakra-project.org
+#
+# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
+# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>
+
+_pkgbasename=libssh2
+pkgname=lib32-$_pkgbasename
+pkgver=1.2.7
+pkgrel=1
+pkgdesc="A library implementing the SSH2 protocol as defined by Internet Drafts (32-bit)"
+arch=('x86_64')
+url="http://www.libssh2.org/"
+license=('BSD')
+depends=('lib32-zlib' 'lib32-libgcrypt' 'lib32-openssl' $_pkgbasename)
+makedepends=(gcc-multilib)
+options=('!libtool')
+source=("http://www.libssh2.org/download/$_pkgbasename-$pkgver.tar.gz")
+md5sums=('a5d78344886f1282e4008c09bf568076')
+
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  cd ${srcdir}/${_pkgbasename}-${pkgver}
+
+  ./configure \
+      --with-libgcrypt \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --libdir=/usr/lib32
+  make
+}
+
+package() {
+  cd ${srcdir}/${_pkgbasename}-${pkgver}
+
+  make DESTDIR=${pkgdir} install
+
+  rm -rf "${pkgdir}"/usr/{share,bin,include}
+}