added lib32-gnutls

lib32-gnutls/PKGBUILD

@@ -0,0 +1,37 @@
+# Lib32 Packages for Chakra, part of chakra-project.org
+#
+# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
+# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>
+
+_pkgbasename=gnutls
+pkgname=lib32-$_pkgbasename
+pkgver=2.8.6
+pkgrel=1
+pkgdesc="A library which provides a secure layer over a reliable transport layer (32-bit)"
+arch=('x86_64')
+license=('GPL3' 'LGPL')
+url="http://www.gnu.org/software/gnutls/"
+options=('libtool')
+# uses built-in libtasn1 for the moment
+depends=(lib32-{gcc-libs,readline,libgcrypt,zlib})
+makedepends=('gcc-multilib')
+source=(ftp://ftp.gnu.org/gnu/gnutls/${_pkgbasename}-${pkgver}.tar.bz2)
+md5sums=('eb0a6d7d3cb9ac684d971c14f9f6d3ba')
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  cd ${srcdir}/${_pkgbasename}-${pkgver}
+  ./configure --prefix=/usr --libdir=/usr/lib32 \
+    --with-zlib --disable-guile
+  make
+}
+
+package() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+}