# Maintainer: Francesco Marinucci <framari [at] opmbx [dot] org>
# CCR Maintainer : ahjolinna <ahjolinna@ovi.com>
 
pkgname=lib32-qtcurve-qt4
pkgver=1.8.18
pkgrel=3
pkgdesc='A configurable set of widget styles for KDE and Gtk. Qt4-only version. Multilib.'
arch=('x86_64')
url='https://github.com/QtCurve/qtcurve'
license=('LGPL')
groups=('qtcurve')
depends=('lib32-qt')
makedepends=('cmake' 'gcc-multilib' 'automoc4' 'lib32-qt')
source=("qtcurve-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
md5sums=('422d1876d944bb278855f320eda19368')
 
prepare() {
  cd qtcurve-$pkgver
  [ -d b ] || mkdir b
 
  # export multilib parameters
  # and QT_BUILD_KEY workaround
  export CC="gcc -m32 -I$srcdir"
  export CXX="g++ -m32 -I$srcdir"
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
}
 
build() {
  cd qtcurve-$pkgver/b
  cmake .. -DCMAKE_BUILD_TYPE=Release \
           -DCMAKE_INSTALL_PREFIX=/usr \
           -DQT_PLUGINS_DIR=/usr/lib32/qt/plugins \
           -DQT_LIBRARY_DIR=/usr/lib32 \
           -DLIB_INSTALL_DIR=/usr/lib32 \
           -DQTC_QT4_ENABLE_KDE=false \
           -DENABLE_GTK2=false \
           -DENABLE_QT5=false
  make
}
 
package() {
  cd qtcurve-$pkgver/b/qt4
  make DESTDIR="$pkgdir" install
}