# Lib32 Packages for Chakra, part of chakra-project.org
#
# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>

pkgname=lib32-curl
_pkgname=curl
pkgver=7.39.0
pkgrel=1
pkgdesc="An URL retrival utility and library (32-bit)"
arch=('x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('lib32-libssh2' 'lib32-krb5' "${_pkgname}=${pkgver}")
source=("http://curl.haxx.se/download/$_pkgname-$pkgver.tar.gz"{,.asc})
md5sums=('a944b069ac70c3e574c25def6e1d6b2f'
         'SKIP')

build() {
  cd "$_pkgname-$pkgver"

  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  ./configure \
      --prefix=/usr \
      --mandir=/usr/share/man \
      --libdir=/usr/lib32 \
      --disable-dependency-tracking \
      --disable-ldap \
      --disable-ldaps \
      --enable-ipv6 \
      --enable-manual \
      --enable-threaded-resolver \
      --enable-versioned-symbols \
      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
      --with-gssapi \
      --with-random=/dev/urandom \
      --without-libidn

  make
}

package() {
  cd "$_pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  rm -rf "${pkgdir}"/usr/{share,bin}
  
  # license
  install -d "$pkgdir/usr/share/licenses"
  ln -s "$_pkgname" "$pkgdir/usr/share/licenses/$pkgname"

  # devel
  find "${pkgdir}/usr/include/curl" -type f -not -name curlbuild.h -delete
  mv "$pkgdir/usr/include/curl/curlbuild.h" "$pkgdir/usr/include/$_pkgname/curlbuild-32.h"
}