# Lib32 Packages for Chakra, part of chakra-project.org
#
# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>
# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>

_pkgbasename=util-linux-ng
pkgname=lib32-$_pkgbasename
pkgver=2.19
pkgrel=1
pkgdesc="Miscellaneous system utilities for Linux (32-bit)"
url="http://userweb.kernel.org/~kzak/util-linux-ng/"
arch=('x86_64')
depends=('lib32-glibc' $_pkgbasename=$pkgver)
makedepends=('gcc-multilib')
license=('GPL2')
options=('!libtool' '!emptydirs')
source=(ftp://ftp.kernel.org/pub/linux/utils/${_pkgbasename}/v${pkgver}/util-linux-${pkgver}.tar.bz2)

md5sums=('590ca71aad0b254e2631d84401f28255')

build() {
  cd "${srcdir}/util-linux-${pkgver}"

  # hardware clock
  sed -e 's%etc/adjtime%var/lib/hwclock/adjtime%' -i hwclock/hwclock.c
  mkdir -p "${pkgdir}/var/lib/hwclock"

  export CC="gcc -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  autoreconf
  automake
  ./configure --without-ncurses --libdir=/usr/lib32

#  make -C shlibs
   make
}

package() {
  cd "${srcdir}/util-linux-${pkgver}"

#  make -C shlibs DESTDIR="${pkgdir}" install
   make DESTDIR="${pkgdir}" install

  # remove files
  rm -rf "${pkgdir}"/{sbin,bin}
  rm -rf "${pkgdir}"/usr/{include,share,sbin,bin}
}