# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Chaiwat Suttipongsakul <cwt114@gmail.com>

_pkgbasename=libdatrie
pkgname=lib32-${_pkgbasename}
pkgver=0.2.9
pkgrel=1
pkgdesc='Implementation of double-array structure for representing trie, as proposed by Junichi Aoe.'
url='http://linux.thai.net/projects/datrie'
license=('LGPL')
arch=('x86_64')
depends=('lib32-glibc' "${_pkgbasename}=${pkgver}")
makedepends=('gcc-multilib')
source=("http://linux.thai.net/pub/thailinux/software/libthai/libdatrie-${pkgver}.tar.xz")
sha256sums=('d980713e7ad8e19cf3b54ee0173782b94332af8e7e4e936dde01d2cd72e1da1d')

build() {
  cd ${_pkgbasename}-${pkgver}

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

  ./configure \
    --prefix='/usr' \
    --libdir='/usr/lib32' \
    --disable-static
  make
}

package() {
  cd ${_pkgbasename}-${pkgver}

  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/{bin,include,share}
}

# vim: ts=2 sw=2 et: