# Lib32 Packages for Chakra, part of chakra-project.org
#
# maintainer (x86_64): Giuseppe Calà <jiveaxe@gmail.com>
# maintainer (x86_64): Anke Boersma <abveritas[at]chakra-project[dot]org>

_pkgbasename=freetype2-ubuntu
pkgname=lib32-$_pkgbasename
pkgver=2.4.6
_pkgver=2.4.4-2
pkgrel=1
pkgdesc="TrueType font rendering library (32-bit) with infinality patch"
arch=(x86_64)
license=('GPL')
url="http://freetype.sourceforge.net"
depends=('lib32-zlib' $_pkgbasename)
makedepends=(gcc-multilib)
conflicts=('lib32-freetype2')
provides=("lib32-freetype2=$pkgver")
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2
        https://launchpad.net/ubuntu/oneiric/+source/freetype/$_pkgver/+files/freetype_$_pkgver.diff.gz
        apple-offset.patch
        enable-valid.patch)

md5sums=('5e6510613f612809d2d7862592b92ab7'
         '8a170e472c2b1d60dff0987722a290d3'
         '1c964f90ae90aa391af574ceb0814cda'
         '214119610444c9b02766ccee5e220680')

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "${srcdir}/freetype-${pkgver}"

  msg "applying apple-offset.patch..."
  patch -Np1 -i "${srcdir}/apple-offset.patch"

  msg "applying enable-valid.patch..."
  patch -Np1 -i "${srcdir}/enable-valid.patch"

  ./configure --prefix=/usr --libdir=/usr/lib32
  make
}

package() {
  cd "${srcdir}/freetype-${pkgver}"

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/{include,share,bin}
}