# toolchain build order: 
# toolchain build order: lib32-glibc>binutils->lib32-gcc->binutils->lib32-glibc

_pkgbasename=glibc
pkgname=lib32-$_pkgbasename
pkgver=2.26
pkgrel=1
_commit=633e2f7f3d88df6427aa3a7a984d3a6b796d9611  # release/2.26/master
pkgdesc="GNU C Library (32-bit)"
arch=('x86_64')
url="http://www.gnu.org/software/libc"
license=('GPL' 'LGPL')
depends=($_pkgbasename>=$pkgver)
makedepends=('gcc>=5.2' 'git' 'lib32-gcc-libs')
options=('!strip' 'staticlibs' '!emptydirs')

source=(git+https://sourceware.org/git/glibc.git#commit=${_commit}
        lib32-glibc.conf
        0001-manual-Update-to-mention-ENODEV-for-ttyname-and-ttyn.patch
        0002-linux-ttyname-Update-a-reference-to-kernel-docs-for-.patch
        0003-linux-ttyname-Change-return-type-of-is_pty-from-int-.patch
        0004-linux-ttyname-_r-Make-tty-checks-consistent.patch
        0005-linux-ttyname-_r-Don-t-bail-prematurely-BZ-22145.patch
        0006-linux-ttyname-_r-Add-tests.patch
        bz20338.patch)

md5sums=('SKIP'
         '6e052f1cb693d5d3203f50f9d4e8c33b'
         '2bb2dfa660fbb4b349f844459f79d5a1'
         '299316b1a35426eadf3301a3fad170be'
         '41d212e3f8d838bff341102679b2af09'
         '8a886e84f950caf2ad1c37cc3a456339'
         'fc5af427803b139d9753230849053458'
         'eb4e1836f4f3721f1215450a2cca3523'
         'dc0d3ad59aeaaf591b085a77de6e03e9')

prepare() {
  mkdir -p glibc-build

  cd glibc

  local i; for i in ${source[@]}; do
    case ${i%::*} in
      *.patch)
        msg2 "Applying ${i}"
        patch -p1 -i "$srcdir/${i}"
        ;;
    esac
  done
}

build() {
  cd ${srcdir}/glibc-build

  echo "slibdir=/usr/lib32" >> configparms
  echo "rtlddir=/usr/lib32" >> configparms
  echo "sbindir=/usr/sbin" >> configparms
  echo "rootsbindir=/usr/sbin" >> configparms

  #export CFLAGS="${CFLAGS} -mno-tls-direct-seg-refs"
  export CC="gcc -m32 -mstackrealign"
  export CXX="g++ -m32 -mstackrealign"

  # remove fortify for building libraries
  CPPFLAGS=${CPPFLAGS/-D_FORTIFY_SOURCE=2/}

  ../glibc/configure \
      --prefix=/usr \
      --libdir=/usr/lib32 \
      --libexecdir=/usr/lib32 \
      --with-headers=/usr/include \
      --with-bugurl=https://code.chakralinux.org/ \
      --enable-add-ons \
      --enable-bind-now \
      --enable-lock-elision \
      --enable-multi-arch \
      --enable-obsolete-nsl \
      --enable-obsolete-rpc \
      --enable-stack-protector=strong \
      --enable-stackguard-randomization \
      --disable-profile \
      --disable-werror \
      i686-pc-linux-gnu

  # build libraries with fortify disabled
  echo "build-programs=no" >> configparms
  make

  # re-enable fortify for programs
  sed -i "/build-programs=/s#no#yes#" configparms

  echo "CC += -D_FORTIFY_SOURCE=2" >> configparms
  echo "CXX += -D_FORTIFY_SOURCE=2" >> configparms
  make
}

check() {
  cd glibc-build

  # remove fortify in preparation to run test-suite
  sed -i '/FORTIFY/d' configparms

  # some failures are "expected"
  make check || true
}

package() {
  cd glibc-build

  make install_root=${pkgdir} install

  rm -rf ${pkgdir}/{etc,sbin,usr/{bin,sbin,share},var}

  # We need to keep 32 bit specific header files
  find ${pkgdir}/usr/include -type f -not -name '*-32.h' -delete

  # Dynamic linker
  mkdir ${pkgdir}/usr/lib
  ln -s ../lib32/ld-linux.so.2 ${pkgdir}/usr/lib/

  # Add lib32 paths to the default library search path
  install -Dm644 "$srcdir/lib32-glibc.conf" "$pkgdir/etc/ld.so.conf.d/lib32-glibc.conf"

  # Symlink /usr/lib32/locale to /usr/lib/locale
  ln -s ../lib/locale "$pkgdir/usr/lib32/locale"

  # Do not strip the following files for improved debugging support
  # ("improved" as in not breaking gdb and valgrind...):
  #   ld-${pkgver}.so
  #   libc-${pkgver}.so
  #   libpthread-${pkgver}.so
  #   libthread_db-1.0.so

  cd $pkgdir
  strip $STRIP_BINARIES usr/lib32/getconf/*
  strip $STRIP_STATIC usr/lib32/lib{anl,BrokenLocale,c{,_nonshared},crypt}.a \
                        usr/lib32/lib{dl,g,ieee,mcheck,nsl,pthread{,_nonshared}}.a \
                        usr/lib32/lib{resolv,rpcsvc,rt,util,m}.a
  strip $STRIP_SHARED usr/lib32/lib{anl,BrokenLocale,cidn,crypt}-${pkgver}.so \
                        usr/lib32/libnss_{compat,db,dns,files,hesiod,nis,nisplus}-*.so \
                        usr/lib32/lib{dl,m,nsl,resolv,rt,util}-${pkgver}.so \
                        usr/lib32/lib{memusage,pcprofile,SegFault}.so \
                        usr/lib32/{audit,gconv}/*.so || true
}