# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=kbd
pkgver=2.6.4
pkgrel=1
pkgdesc="Keytable files and keyboard utilities"
arch=('x86_64')
url="https://kbd-project.org/"
license=('GPL-2.0-or-later')
depends=('glibc')
makedepends=('check')
source=(https://www.kernel.org/pub/linux/utils/${pkgname}/${pkgname}-${pkgver}.tar.xz
	${pkgname}-${pkgver}-backspace-1.patch)
sha256sums=(519f8d087aecca7e0a33cd084bef92c066eb19731666653dcc70c9d71aa40926
	8be28dcb11420624a500f2ea4fe975f771174bffee50e54ec8cd295a2dec104e)

prepare() {
	cd ${pkgname}-${pkgver}

	patch -Np1 -i ${srcdir}/${pkgname}-${pkgver}-backspace-1.patch

	sed -i '/RESIZECONS_PROGS=/s/yes/no/' configure
	sed -i 's/resizecons.8 //' docs/man/man8/Makefile.in
}

build() {
	cd ${pkgname}-${pkgver}

	${CONFIGURE} --disable-vlock

	make
}

package() {
	cd ${pkgname}-${pkgver}

	make DESTDIR=${pkgdir} install

	install -vdm755 ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
	cp -R -v docs/doc -T ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}