# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=util-linux
pkgver=2.40.2
pkgrel=1
pkgdesc="Miscellaneous system utilities for Linux"
arch=('x86_64')
url="https://git.kernel.org/pub/scm/utils/util-linux/util-linux.git/"
license=('BSD-2-Clause'
	'BSD-3-Clause'
	'BSD-4-Clause-UC'
	'GPL-2.0-only'
	'GPL-2.0-or-later'
	'GPL-3.0-or-later'
	'ISC'
	'LGPL-2.1-or-later'
	'LicenseRef-PublicDomain')
groups=('base')
depends=('glibc' 'coreutils' 'file' 'libxcrypt' 'ncurses' 'readline' 'shadow' 'zlib')
makedepends=('systemd')
options=('strip')
source=(https://www.kernel.org/pub/linux/utils/util-linux/v${pkgver%.*}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(9afcd201f39429d2db2492aeb13dba5e75d6cc50682b732dca35643bd5f092e3)

build() {
	cd ${pkgname}-${pkgver}

	${CONFIGURE}              \
	    --runstatedir=/run    \
	    --bindir=/usr/bin     \
	    --sbindir=/usr/sbin   \
	    --disable-chfn-chsh   \
	    --disable-login       \
	    --disable-nologin     \
	    --disable-su          \
	    --disable-setpriv     \
	    --disable-runuser     \
	    --disable-pylibmount  \
	    --disable-liblastlog2 \
	    --disable-static      \
	    --without-python      \
	    ADJTIME_PATH=/var/lib/hwclock/adjtime \
	    --docdir=/usr/share/doc/${pkgname}-${pkgver}

	make
}

package() {
	cd ${pkgname}-${pkgver}

	make DESTDIR=${pkgdir} install

	install -vdm755 ${pkgdir}/var/lib/hwclock

	install -vdm755 ${pkgdir}/etc
	cat > ${pkgdir}/etc/adjtime << "EOF"
0.0 0 0.0
0
LOCAL
EOF

}