# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=coreutils
pkgver=9.5
pkgrel=1
pkgdesc="The basic file, shell and text manipulation utilities of the GNU operating system"
arch=('x86_64')
url="https://www.gnu.org/software/coreutils/"
license=('GPL-3.0-or-later' 'GFDL-1.3-or-later')
groups=('base')
depends=('glibc' 'gmp' 'attr' 'acl' 'libcap' 'openssl')
source=(https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.xz
	${pkgname}-${pkgver}-i18n-2.patch)
sha256sums=(cd328edeac92f6a665de9f323c93b712af1858bc2e0d88f3f7100469470a1b8a
	99f1553ce9b7ded634bb56dac14ba6e439fc124daf8da436ee4cda1fd286f4a2)

prepare() {
	cd ${pkgname}-${pkgver}

	patch -Np1 -i ${srcdir}/${pkgname}-${pkgver}-i18n-2.patch

	autoreconf -fiv
}

build() {
	cd ${pkgname}-${pkgver}

	FORCE_UNSAFE_CONFIGURE=1 \
	${CONFIGURE}             \
	    --enable-no-install-program=kill,uptime

	make
}

package() {
	cd ${pkgname}-${pkgver}

	make DESTDIR=${pkgdir} install

	install -vdm755 ${pkgdir}/usr/sbin ${pkgdir}/usr/share/man/man8
	mv -v ${pkgdir}/usr/bin/chroot ${pkgdir}/usr/sbin
	mv -v ${pkgdir}/usr/share/man/man1/chroot.1 ${pkgdir}/usr/share/man/man8/chroot.8
	sed -i 's/"1"/"8"/' ${pkgdir}/usr/share/man/man8/chroot.8
}